# Author: Ika, 2013-07-24
set term svg size 800,600 enhanced font 'Times,12'
set output 'Second_Order_Taylor.svg'
set multiplot
set xlabel "x"
set ylabel "y"
set zlabel "z"
set xrange [-1.0:2.0]
set yrange [-0.5:2.0]
set zrange [-6.0:10.0]
set box
unset colorbox
#set view 65,45
set style fill solid 0.30 border
set cntrparam levels auto 20
set contour base
set isosamples 60,60
set samples 60,60
set pm3d
set hidd
unset key
set ticslevel 0
i = {0.0,1.0}
# Draw the surface of f(x,y) = e^x log(1+y)
set palette defined (-1 "blue", 1 "pink")
splot exp(x)*log(1+y)
# Draw the surface of f(x,y) = y+xy-y^2/2
set palette defined (-1 "red", 1 "orange")
splot y+x*y-y*y/2
# Draw the lines
unset cntrparam
unset contour
set isosamples 20,20
set samples 20,20
unset pm3d
unset hidd
# Draw the lines of f(x,y) = e^x log(1+y)
splot exp(x)*log(1+y) lt 2 lc rgb "black" lw 0.1
# Draw the lines of f(x,y) = y+xy-y^2/2
splot y+x*y-y*y/2 lt 2 lc rgb "black" lw 0.1
unset multiplot
set term x11
set output
ترخيص
أنا، صاحب حقوق التأليف والنشر لهذا العمل، أنشر هذا العمل تحت الرخصة التالية:
نسب العمل إلى مُؤَلِّفه – يلزم نسب العمل إلى مُؤَلِّفه بشكل مناسب وتوفير رابط للرخصة وتحديد ما إذا أجريت تغييرات. بالإمكان القيام بذلك بأية طريقة معقولة، ولكن ليس بأية طريقة تشير إلى أن المرخِّص يوافقك على الاستعمال.
الإلزام بترخيص المُشتقات بالمثل – إذا أعدت إنتاج المواد أو غيرت فيها، فيلزم أن تنشر مساهماتك المُشتقَّة عن الأصل تحت ترخيص الأصل نفسه أو تحت ترخيص مُتوافِقٍ معه.